5ちゃんねる ★スマホ版★ ■掲示板に戻る■ 全部 1- 最新50  

■ このスレッドは過去ログ倉庫に格納されています

QuickTimeスレッド・Part8

1 :名称未設定:04/06/26 00:29 ID:buYD8Ktg
アップル - QuickTime
http://www.apple.co.jp/quicktime/
アップル - QuickTime - Tools & Tips
http://www.apple.co.jp/quicktime/tools_tips/

●過去スレ
Part0:http://pc.2ch.net/test/read.cgi/mac/1000565167/
Part1:http://pc.2ch.net/test/read.cgi/mac/1013555006/
Part2:http://pc.2ch.net/test/read.cgi/mac/1023288952/
Part3:http://pc.2ch.net/test/read.cgi/mac/1029506601/
Part4:http://pc.2ch.net/test/read.cgi/mac/1040692571/
Part5:http://pc.2ch.net/test/read.cgi/mac/1049245565/
Part6:http://pc.2ch.net/test/read.cgi/mac/1060726096/
Part7:http://pc5.2ch.net/test/read.cgi/mac/1073830200/

●関連スレ
iMovieを使い倒そう(iMovie2,3,4) part4
http://pc5.2ch.net/test/read.cgi/mac/1086315649/l10n
Final Cut Expressスレッド
http://pc5.2ch.net/test/read.cgi/mac/1042039294/l10n
MPEG AVI MOV 総合スレッド 5
http://pc5.2ch.net/test/read.cgi/mac/1080576722/l10n
【初心者に】Mac de DivX Part2【やさしい】
http://pc5.2ch.net/test/read.cgi/mac/1077169163/l10n
Mac de DVD Ripping Part8
http://pc5.2ch.net/test/read.cgi/mac/1077949462/l10n
【ラジオ】macでネット放送局【ストリーミング】
http://pc5.2ch.net/test/read.cgi/mac/1049695802/l10n

484 :名称未設定:04/09/16 00:25:39 ID:BUG6pvop
(*
スクリプト名:Export_as_MOV (名前はお好きなように)
用途:QuickTime Player で書き出しのバッチ処理をする。
要件:OS X、QuickTime6以降、QuickTime Pro
使用法:このスクリプトをアプリケーションとして保存。
 1. 動画ファイル(複数可)をこのスクリプトのアイコンにドロップ。
 2. QuickTime書き出し設定ファイル(別スクリプトで作成)を選択。
 3. 保存先フォルダを選択。
 4. 後は待つだけ。
その他:OS 9 で使う場合は
 1. スクリプト中の as Unicode text を as string に置き換える。
 2. say "finished" を削除。
 3. まだ他にもあったと思うが、もう忘れた!
*)
(* 続く *)

485 :名称未設定:04/09/16 00:27:23 ID:BUG6pvop
property timeoutHours : 48 -- 書き出しのタイムアウトするまでの時間。十分に大きな値にする。

on open dropitems
tell application "QuickTime Player"
activate
close every movie saving ask
set exportSettingsFile to choose file with prompt "QT Export Settings File"
set destinationDir to choose folder with prompt "Destination Folder"
repeat with inputFile in dropitems
set outputFileUtxt to (destinationDir as Unicode text) & my getBasename(inputFile) & ".mov"
(* 上の拡張子 ".mov" は書き出すフォーマットに応じて書き換えること。*)
(* 続く *)


486 :名称未設定:04/09/16 00:28:20 ID:BUG6pvop
try
open inputFile
with timeout of (timeoutHours * hours) seconds
export movie 1 to file outputFileUtxt as QuickTime movie using settings exportSettingsFile
(* 上の as QuickTime movie も書き出すフォーマットに応じて書き換える。
例:as MPEG4, as AIFF, as wave, ..., etc.『用語説明』の「export」を参照。*)
end timeout
close movie 1 saving no
on error errMsg number errNum
activate
beep
display dialog errMsg & " (" & errNum & ")"
try
close movie 1 saving no
end try
end try
end repeat
end tell
say "finished"
end open
(* 続く *)

487 :名称未設定:04/09/16 00:29:11 ID:BUG6pvop
-- ファイル名から拡張子を取り除くサブルーチン
on getBasename(theFile)
tell application "Finder" to set thisName to name of theFile
set thisList to string2list(thisName, ".")
if (count of thisList) > 1 then
return list2string(items 1 thru -2 of thisList, ".") as Unicode text
else
return thisName
end if
end getBasename

-- 文字列をリストに変換するサブルーチン
on string2list(theString, theDelim)
set lastDelim to AppleScript's text item delimiters
set AppleScript's text item delimiters to theDelim
set theList to every text item of theString
set AppleScript's text item delimiters to lastDelim
return theList
end string2list
(* 続く *)

488 :名称未設定:04/09/16 00:29:40 ID:BUG6pvop
-- リストを文字列に変換するサブルーチン
on list2string(theList, theDelim)
set lastDelim to AppleScript's text item delimiters
set AppleScript's text item delimiters to theDelim
set theString to theList as string
set AppleScript's text item delimiters to lastDelim
return theString
end list2string


(* エスケープ文字の入力が問題なければ、下の方が簡単。
on getBasename(theFile)
return do shell script "x=\"$(basename " & quoted form of POSIX path of theFile & ")\"; echo \"${x%.*}\""
end getBasename
*)

(* End of Script *)


489 :名称未設定:04/09/16 00:31:31 ID:BUG6pvop
(*
スクリプト名:Save_QTES-MOV (名前はお好きなように)
用途:QuickTime書き出し設定ファイルを作成する。
要件:OS X、QuickTime6以降、QuickTime Pro
使用法:このスクリプトをアプリケーション、またはコンパイル済みスクリプトとして保存。
 1. QuickTime Player を用いて、手動で QuickTimeムービー等を書き出す。
  (1、2秒の短いクリップで十分)
 2. ムービーのウィンドウは開いたまま、このスクリプトを起動する。
 3. 書き出し設定ファイルに分かりやすい名前を付けて保存する。
*)
(* 続く *)

490 :名称未設定:04/09/16 00:31:55 ID:BUG6pvop
tell application "QuickTime Player"
activate
if not (exists movie 1) then error "No movie is open."
stop every movie
set exportSettingsFile to choose file name with prompt "QT Export Settings File - MOV"
save export settings movie 1 for QuickTime movie to exportSettingsFile
(* 上の for QuickTime movie は書き出すフォーマットに応じて書き換える。
例:for MPEG4, for AIFF, for wave, ..., etc.『用語説明』の「save export settings」を参照。*)
say "finished"
end tell

(* End of Script *)


491 :名称未設定:04/09/16 00:39:27 ID:BUG6pvop
>>489-490 のスクリプトで保存した書き出し設定ファイルを使って
>>484-488 のスクリプトでバッチ処理をする。

223 KB
★スマホ版★ 掲示板に戻る 全部 前100 次100 最新50

read.cgi ver 05.04.00 2017/10/04 Walang Kapalit ★
FOX ★ DSO(Dynamic Shared Object)